Skrypt ognia C47

Mam skrypt od samolotu C47

; ****************************************************
; McDONNELL DOUGLAS C-47 SKYTRAIN
; ****************************************************
; 25/03/04
; By Trenchfeet
; ****************************************************

_plane = _this select 0
_delay = 0.01
_color1 = [8.8,8.8,0,0.99]
_color2 = [0.009,0.00,0,0.099]
_white = [0,0,0,0]
_a=0

#begin
_nrand = random(100)
?(getdammage _plane) <= 0.1 : exit
?_nrand >= 50: goto "right"
?_nrand >= -10: goto "left"
goto "begin"



#right
#Burn
?(getdammage _plane) <= 0.85 : exit
_color1 = [8.8,8.8,0, 0.99]
_color2 = [0.009, 0.00, 0, 0.99]
_colorWhite = [0.8,0.8,0.8,0]
_colorBlack = [0.0,0.0,0.0,0.5]
_whitereal = [0,0,0,0]
drop ["cl_fire", "", "Billboard", 1, 1, [3.5,6,-1], [0,0,0], 0, 1.1, 1, 0.5, [Random 7, 9, 6],[_color1, _color2, _color2, _whitereal],[0],0.2,0.6,"","",_plane]
drop ["cl_basic", "", "Billboard", 1, 4, [3.5,6,-1], [0,0,0], 0, 1.1, 1, 0.5, [Random 7, 9, 6],[_color2, _color2, _color2, _whitereal],[0],0.2,0.6,"","",_plane]
_smoke = Getdammage _plane-0.1
_color2 = [0.009,0.00,0,_smoke]
drop ["cl_fire", "", "Billboard", 1, 5, [-3.5,6,-1], [0,0,0], 0, 1, 1, 0.5, [2, 6],[_color2, _color2, _color2, _white],[0],0.7,0.5,"","",_plane]
?(_a == 0): [_plane] exec "\mtyc47\damage.sqs"
_a=_a+100
~0.01
goto "Burn"



#left
#Burn2
?(getdammage _plane) <= 0.85 : exit
_color1 = [8.8,8.8,0, 0.99]
_color2 = [0.009, 0.00, 0, 0.99]
_colorWhite = [0.8,0.8,0.8,0]
_colorBlack = [0.0,0.0,0.0,0.5]
_whitereal = [0,0,0,0]
drop ["cl_fire", "", "Billboard", 1, 1, [-3.5,6,-1], [0,0,0], 0, 1.1, 1, 0.5, [Random 7, 9, 6],[_color1, _color2, _color2, _whitereal],[0],0.2,0.6,"","",_plane]
drop ["cl_basic", "", "Billboard", 1, 4, [-3.5,6,-1], [0,0,0], 0, 1.1, 1, 0.5, [Random 7, 9, 6],[_color2, _color2, _color2, _whitereal],[0],0.2,0.6,"","",_plane]
_smoke = Getdammage _plane-0.1
_color2 = [0.009,0.00,0,_smoke]
drop ["cl_fire", "", "Billboard", 1, 5, [3.5,6,-1], [0,0,0], 0, 1, 1, 0.5, [2, 6],[_color2, _color2, _color2, _white],[0],0.7,0.5,"","",_plane]
?(_a == 0): [_plane] exec "\mtyc47\damage.sqs"
_a=_a+100
~0.01
goto "Burn2"

Ale nie wiem jak go przerobić tak by powodował tylko ogień z silników , bo teraz ma w sobie równiesz gaszenie silników oraz rozmowy pilotów o ogniu , a nie wiem jak to usunąć

Tu rozmów nie ma, więc pewnie są w damage.sqs

Wklej jeszcze to damage.sqs - skrypt tutaj zapętla się dopóki dammage samolotu nie będzie mniejsze od .85

; ****************************************************
; McDONNELL DOUGLAS C-47 SKYTRAIN
; ****************************************************
; 25/03/04
; By Trenchfeet
; ****************************************************

_ju52 = _this select 0
_allparacrew = crew _ju52
_a=0
_inc = 0.002

~2
_ju52 sideChat "Damn it!, We're on fire..."
~2
_ju52 sideChat "Engaging Engine Fire Extinguishers."
goto "EngineExt"

#die
~3
_ju52 sideChat "Its no good...."
_plane setobjecttexture [15,""]
~2
_ju52 sideChat "Can't controll her, she's going down."
~2
_ju52 sideChat "Get ready to jump!"
(group _ju52) setspeedmode "limited"
[_ju52] exec "\MTYC47\light.sqs"
_ju52 animate ["mtydoor",1];
_ju52 say "C47outeropen";
[_ju52] exec "\MTYC47\wind.sqs"
_plane setobjecttexture [16,"\mtyc47\instra.pac"]
_n=0

? count _allparacrew == 0 : goto "done"
_c = 0

#loop
_a=_a+0.1
?(not alive _ju52): Exit
_damage = getdammage _ju52
~0.1
_ju52 setdamage (_damage+_inc)
?(_a >= 3.7): goto "jump"
goto "loop"

#jump
_ju52 sideChat "Everyone Out!"
?(not alive _ju52): Exit
unassignvehicle (_allparacrew select _c)
(_allparacrew select _c) action ["GETOUT",_ju52]
_chute = "ParachuteEast" createvehicle [0,0,0]
(_allparacrew select _c) moveindriver _chute
_x = (GetPos _ju52) Select 0
_y = (GetPos _ju52) Select 1
_z = (GetPos _ju52) Select 2
_chute SetPos [_x -1.9, _y, _z +1]
(_allparacrew select _c) setvelocity (velocity _ju52)
~.6
_c = _c + 1
? _c != count _allparacrew : goto "jump"
#done
exit



;;;;;;Engine Extinguishers -------------

#EngineExt

_delay = 0.01
_color1 = [8.8,8.8,0,0.99]
_color2 = [0.009,0.00,0,0.099]
_white = [1,1,1,1]
_a=0

#Burn
?(getdammage _ju52) <= 0.1 : exit
_color1 = [8.8,8.8,0, 0.99]
_color2 = [0.009, 0.00, 0, 0.99]
_colorWhite = [0.8,0.8,0.8,0]
_colorBlack = [0.0,0.0,0.0,0.5]
_whitereal = [0,0,0,0]
_plane setobjecttexture [15,"\mtyc47\instra.pac"]
drop ["CL_basic", "", "Billboard", 1, 1, [3.5,6,-1], [0,0,0], 0, 1.1, 1, 0.5, [Random 3, 6, 5],[_white, _white, _white, _whitereal],[0],0.2,0.6,"","",_ju52]
drop ["cl_basic", "", "Billboard", 1, 1, [3.5,6,-1], [0,0,0], 0, 1.1, 1, 0.5, [Random 3, 6, 5],[_white, _white, _white, _whitereal],[0],0.2,0.6,"","",_ju52]
drop ["CL_basic", "", "Billboard", 1, 1, [-3.5,6,-1], [0,0,0], 0, 1, 1, 0.5, [2, 5],[_white, _white, _white, _white],[0],0.7,0.5,"","",_ju52]
drop ["CL_basic", "", "Billboard", 1, 1, [-3.5,6,-1], [0,0,0], 0, 1.1, 1, 0.5, [Random 3, 6, 5],[_white, _white, _white, _whitereal],[0],0.2,0.6,"","",_ju52]
drop ["cl_basic", "", "Billboard", 1, 1, [-3.5,6,-1], [0,0,0], 0, 1.1, 1, 0.5, [Random 3, 6, 5],[_white, _white, _white, _whitereal],[0],0.2,0.6,"","",_ju52]
drop ["CL_basic", "", "Billboard", 1, 1, [3.5,6,-1], [0,0,0], 0, 1, 1, 0.5, [2, 5],[_white, _white, _white, _white],[0],0.7,0.5,"","",_ju52]
~0.01
_a=_a+1
?(_a >= 180): goto "decide"
goto "Burn"

#decide
_nrand = random(100)
?(getdammage _ju52) <= 0.1 : exit
?_nrand >= 70: goto "die"
?_nrand >= 55: goto "live"
?_nrand >= 30: goto "die"
?_nrand >= 12: goto "live"
?_nrand >= -10: goto "die"
goto "decide"

#live
_ju52 setdammage 0
_plane setobjecttexture [15,""]
_ju52 sideChat "Its Ok, Its OK, the fires out."
~3
_ju52 sideChat "That was close!"
exit

Skrypt dosyć prosty...pierwsze jest dym silników, i przez pewien czas będzie się palić. Potem losowo wybiera czy silniki zgaszone (#live) czy trzeba opuścić samolot (#die). W całym skrypcie są też rozmowy.

Jeśli nie chcesz tego, w pierwszym skrypcie usuń wszystkie: ?(_a == 0): [_plane] exec "\mtyc47\damage.sqs"
Wtedy powinny się silniki palić w nieskonczoność...i jeszcze dłużej...

Noo...to chyba tyle...w teorii pownno działać